1/*
2 * linux/arch/unicore/boot/compressed/vmlinux.lds.in
3 *
4 * Code specific to PKUnity SoC and UniCore ISA
5 *
6 * Copyright (C) 2001-2010 GUAN Xue-tao
7 *
8 * This program is free software; you can redistribute it and/or modify
9 * it under the terms of the GNU General Public License version 2 as
10 * published by the Free Software Foundation.
11 */
12OUTPUT_ARCH(unicore32)
13ENTRY(_start)
14SECTIONS
15{
16  /DISCARD/ : {
17    /*
18     * Discard any r/w data - this produces a link error if we have any,
19     * which is required for PIC decompression.  Local data generates
20     * GOTOFF relocations, which prevents it being relocated independently
21     * of the text/got segments.
22     */
23    *(.data)
24  }
25
26  . = TEXT_START;
27  _text = .;
28
29  .text : {
30    _start = .;
31    *(.start)
32    *(.text)
33    *(.text.*)
34    *(.fixup)
35    *(.gnu.warning)
36    *(.rodata)
37    *(.rodata.*)
38    *(.piggydata)
39    . = ALIGN(4);
40  }
41
42  _etext = .;
43
44  /* Assume size of decompressed image is 4x the compressed image */
45  _image_size = (_etext - _text) * 4;
46
47  _got_start = .;
48  .got			: { *(.got) }
49  _got_end = .;
50  .got.plt		: { *(.got.plt) }
51  _edata = .;
52
53  . = BSS_START;
54  __bss_start = .;
55  .bss			: { *(.bss) }
56  _end = .;
57
58  .stack		: { *(.stack) }
59  .comment 0		: { *(.comment) }
60}
61
62