1;;  Copyright 2010  Free Software Foundation, Inc.
2;;  Contributed by Bernd Schmidt <bernds@codesourcery.com>.
3;;
4;; This program is free software; you can redistribute it and/or modify
5;; it under the terms of the GNU General Public License as published by
6;; the Free Software Foundation; either version 2 of the License, or
7;; (at your option) any later version.
8;;
9;; This program is distributed in the hope that it will be useful,
10;; but WITHOUT ANY WARRANTY; without even the implied warranty of
11;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
12;; GNU General Public License for more details.
13;;
14;; You should have received a copy of the GNU General Public License
15;; along with this program; if not, write to the Free Software
16;; Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
17
18#include <linux/linkage.h>
19
20	;; ABI considerations for the divide functions
21	;; The following registers are call-used:
22	;; __c6xabi_divi A0,A1,A2,A4,A6,B0,B1,B2,B4,B5
23	;; __c6xabi_divu A0,A1,A2,A4,A6,B0,B1,B2,B4
24	;; __c6xabi_remi A1,A2,A4,A5,A6,B0,B1,B2,B4
25	;; __c6xabi_remu A1,A4,A5,A7,B0,B1,B2,B4
26	;;
27	;; In our implementation, divu and remu are leaf functions,
28	;; while both divi and remi call into divu.
29	;; A0 is not clobbered by any of the functions.
30	;; divu does not clobber B2 either, which is taken advantage of
31	;; in remi.
32	;; divi uses B5 to hold the original return address during
33	;; the call to divu.
34	;; remi uses B2 and A5 to hold the input values during the
35	;; call to divu.  It stores B3 in on the stack.
36
37	.text
38
39ENTRY(__c6xabi_remi)
40	stw	.d2t2	B3, *B15--[2]
41||	cmpgt	.l1	0, A4, A1
42||	cmpgt	.l2	0, B4, B2
43||	mv	.s1	A4, A5
44||	call	.s2	__c6xabi_divu
45
46   [A1]	neg	.l1	A4, A4
47|| [B2]	neg	.l2	B4, B4
48||	xor	.s2x	B2, A1, B0
49||	mv	.d2	B4, B2
50
51   [B0]	addkpc	.s2	_divu_ret_1, B3, 1
52  [!B0] addkpc	.s2	_divu_ret_2, B3, 1
53	nop	2
54_divu_ret_1:
55	neg	.l1	A4, A4
56_divu_ret_2:
57	ldw	.d2t2	*++B15[2], B3
58
59	mpy32	.m1x	A4, B2, A6
60	nop		3
61	ret	.s2	B3
62	sub	.l1	A5, A6, A4
63	nop	4
64ENDPROC(__c6xabi_remi)
65