root/arch/microblaze/kernel/vmlinux.lds.S

   1 /*
   2  * Copyright (C) 2008-2009 Michal Simek <monstr@monstr.eu>
   3  * Copyright (C) 2008-2009 PetaLogix
   4  * Copyright (C) 2006 Atmark Techno, Inc.
   5  *
   6  * This file is subject to the terms and conditions of the GNU General Public
   7  * License. See the file "COPYING" in the main directory of this archive
   8  * for more details.
   9  */
  10 
  11 OUTPUT_ARCH(microblaze)
  12 ENTRY(microblaze_start)
  13 
  14 #include <asm/page.h>
  15 #include <asm-generic/vmlinux.lds.h>
  16 #include <asm/thread_info.h>
  17 
  18 #ifdef __MICROBLAZEEL__
  19 jiffies = jiffies_64;
  20 #else
  21 jiffies = jiffies_64 + 4;
  22 #endif
  23 
  24 SECTIONS {
  25         . = CONFIG_KERNEL_START;
  26         microblaze_start = CONFIG_KERNEL_BASE_ADDR;
  27         .text : AT(ADDR(.text) - LOAD_OFFSET) {
  28                 _text = . ;
  29                 _stext = . ;
  30                 HEAD_TEXT
  31                 TEXT_TEXT
  32                 *(.fixup)
  33                 EXIT_TEXT
  34                 EXIT_CALL
  35                 SCHED_TEXT
  36                 CPUIDLE_TEXT
  37                 LOCK_TEXT
  38                 KPROBES_TEXT
  39                 IRQENTRY_TEXT
  40                 SOFTIRQENTRY_TEXT
  41                 . = ALIGN (4) ;
  42                 _etext = . ;
  43         }
  44 
  45         . = ALIGN (4) ;
  46         __fdt_blob : AT(ADDR(__fdt_blob) - LOAD_OFFSET) {
  47                 _fdt_start = . ;                /* place for fdt blob */
  48                 *(__fdt_blob) ;                 /* Any link-placed DTB */
  49                 . = _fdt_start + 0x8000;        /* Pad up to 32kbyte */
  50                 _fdt_end = . ;
  51         }
  52 
  53         . = ALIGN(16);
  54         RODATA
  55         EXCEPTION_TABLE(16)
  56         NOTES
  57 
  58         /*
  59          * sdata2 section can go anywhere, but must be word aligned
  60          * and SDA2_BASE must point to the middle of it
  61          */
  62         .sdata2 : AT(ADDR(.sdata2) - LOAD_OFFSET) {
  63                 _ssrw = .;
  64                 . = ALIGN(PAGE_SIZE); /* page aligned when MMU used */
  65                 *(.sdata2)
  66         . = ALIGN(8);
  67         _essrw = .;
  68         _ssrw_size = _essrw - _ssrw;
  69         _KERNEL_SDA2_BASE_ = _ssrw + (_ssrw_size / 2);
  70         }
  71 
  72         _sdata = . ;
  73         RW_DATA_SECTION(32, PAGE_SIZE, THREAD_SIZE)
  74         _edata = . ;
  75 
  76         /* Under the microblaze ABI, .sdata and .sbss must be contiguous */
  77         . = ALIGN(8);
  78         .sdata : AT(ADDR(.sdata) - LOAD_OFFSET) {
  79                 _ssro = .;
  80                 *(.sdata)
  81         }
  82 
  83         .sbss : AT(ADDR(.sbss) - LOAD_OFFSET) {
  84                 _ssbss = .;
  85                 *(.sbss)
  86                 _esbss = .;
  87                 _essro = .;
  88                 _ssro_size = _essro - _ssro ;
  89                 _KERNEL_SDA_BASE_ = _ssro + (_ssro_size / 2) ;
  90         }
  91 
  92         . = ALIGN(PAGE_SIZE);
  93         __init_begin = .;
  94 
  95         INIT_TEXT_SECTION(PAGE_SIZE)
  96 
  97         .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) {
  98                 INIT_DATA
  99         }
 100 
 101         . = ALIGN(4);
 102         .init.ivt : AT(ADDR(.init.ivt) - LOAD_OFFSET) {
 103                 __ivt_start = .;
 104                 *(.init.ivt)
 105                 __ivt_end = .;
 106         }
 107 
 108         .init.setup : AT(ADDR(.init.setup) - LOAD_OFFSET) {
 109                 INIT_SETUP(0)
 110         }
 111 
 112         .initcall.init : AT(ADDR(.initcall.init) - LOAD_OFFSET ) {
 113                 INIT_CALLS
 114         }
 115 
 116         .con_initcall.init : AT(ADDR(.con_initcall.init) - LOAD_OFFSET) {
 117                 CON_INITCALL
 118         }
 119 
 120         __init_end_before_initramfs = .;
 121 
 122         .init.ramfs : AT(ADDR(.init.ramfs) - LOAD_OFFSET) {
 123                 INIT_RAM_FS
 124         }
 125 
 126         __init_end = .;
 127 
 128         .bss ALIGN (PAGE_SIZE) : AT(ADDR(.bss) - LOAD_OFFSET) {
 129                 /* page aligned when MMU used */
 130                 __bss_start = . ;
 131                         *(.bss*)
 132                         *(COMMON)
 133                 . = ALIGN (4) ;
 134                 __bss_stop = . ;
 135         }
 136         . = ALIGN(PAGE_SIZE);
 137         _end = .;
 138 
 139         DISCARDS
 140 }