root/arch/um/include/asm/common.lds.S

   1 /* SPDX-License-Identifier: GPL-2.0 */
   2 #include <asm-generic/vmlinux.lds.h>
   3 
   4   .fini      : { *(.fini)    } =0x9090
   5   _etext = .;
   6   PROVIDE (etext = .);
   7 
   8   . = ALIGN(4096);
   9   _sdata = .;
  10   PROVIDE (sdata = .);
  11 
  12   RODATA
  13 
  14   .unprotected : { *(.unprotected) }
  15   . = ALIGN(4096);
  16   PROVIDE (_unprotected_end = .);
  17 
  18   . = ALIGN(4096);
  19   NOTES
  20   EXCEPTION_TABLE(0)
  21 
  22   BUG_TABLE
  23 
  24   .uml.setup.init : {
  25         __uml_setup_start = .;
  26         *(.uml.setup.init)
  27         __uml_setup_end = .;
  28   }
  29         
  30   .uml.help.init : {
  31         __uml_help_start = .;
  32         *(.uml.help.init)
  33         __uml_help_end = .;
  34   }
  35         
  36   .uml.postsetup.init : {
  37         __uml_postsetup_start = .;
  38         *(.uml.postsetup.init)
  39         __uml_postsetup_end = .;
  40   }
  41         
  42   .init.setup : {
  43         INIT_SETUP(0)
  44   }
  45 
  46   PERCPU_SECTION(32)
  47         
  48   .initcall.init : {
  49         INIT_CALLS
  50   }
  51 
  52   .con_initcall.init : {
  53         CON_INITCALL
  54   }
  55 
  56   .exitcall : {
  57         __exitcall_begin = .;
  58         *(.exitcall.exit)
  59         __exitcall_end = .;
  60   }
  61 
  62   .uml.exitcall : {
  63         __uml_exitcall_begin = .;
  64         *(.uml.exitcall.exit)
  65         __uml_exitcall_end = .;
  66   }
  67 
  68   . = ALIGN(4);
  69   .altinstructions : {
  70         __alt_instructions = .;
  71         *(.altinstructions)
  72         __alt_instructions_end = .;
  73   }
  74   .altinstr_replacement : { *(.altinstr_replacement) }
  75   /* .exit.text is discard at runtime, not link time, to deal with references
  76      from .altinstructions and .eh_frame */
  77   .exit.text : { EXIT_TEXT }
  78   .exit.data : { *(.exit.data) }
  79 
  80   .preinit_array : {
  81         __preinit_array_start = .;
  82         *(.preinit_array)
  83         __preinit_array_end = .;
  84   }
  85   .init_array : {
  86         __init_array_start = .;
  87         *(.init_array)
  88         __init_array_end = .;
  89   }
  90   .fini_array : {
  91         __fini_array_start = .;
  92         *(.fini_array)
  93         __fini_array_end = .;
  94   }
  95 
  96    . = ALIGN(4096);
  97   .init.ramfs : {
  98         INIT_RAM_FS
  99   }
 100